Attachment: Fictitious invoice using LinkedIn's address

type.inbound
and 0 < length(filter(attachments, .file_type == "pdf")) < 3
and any(filter(attachments,
               .file_type == "pdf"
               // creator and producer of PDF seen in malicious content
               and (
                 strings.starts_with(beta.parse_exif(.).creator, "wkhtmltopdf")
                 or strings.starts_with(beta.parse_exif(.).producer,
                                        "Qt ",
                                        "Skia"
                 )
               )
        ),
        any(filter(file.explode(.), .scan.ocr.raw is not null),
            regex.icontains(.scan.ocr.raw, '1000 W(?:est)?\.? Maude Ave')
        )
)
// not actually from LinkedIn
and not (
  sender.email.domain.root_domain in ("linkedin.com", "licdn.com")
  and coalesce(headers.auth_summary.dmarc.pass, false)
)
and any(ml.nlu_classifier(body.current_thread.text).topics,
        .name == "Financial Communications" and .confidence != "low"
)